cmake_minimum_required(VERSION 3.22)
project(iap_demo)

set(SRC_ROOT ${CMAKE_CURRENT_SOURCE_DIR}/../../../../../src/)
set(COMMON ${SRC_ROOT}/common)
set(CRYPTO ${SRC_ROOT}/cyclone_crypto)
set(UPDATE ${SRC_ROOT}/cyclone_boot)
set(TCP ${SRC_ROOT}/cyclone_tcp)
set(THIRD_PARTY ${CMAKE_SOURCE_DIR}/../../../../../third_party)
set(TOOLS ${CMAKE_SOURCE_DIR}/../../../../../tools)

set(RESOURCE_COMPILER ${TOOLS}/ResourceCompiler/)

set(CMAKE_C_STANDARD 11)
set(CMAKE_C_STANDARD_REQUIRED ON)
set(CMAKE_C_EXTENSIONS ON)

# Define the build type
if(NOT CMAKE_BUILD_TYPE)
    set(CMAKE_BUILD_TYPE "Debug")
endif()

# Enable compile command to ease indexing with e.g. clangd
set(CMAKE_EXPORT_COMPILE_COMMANDS TRUE)

# Core project settings
message("Build type: " ${CMAKE_BUILD_TYPE})

# Enable CMake support for ASM and C languages
enable_language(C ASM)

# Create an executable object type
add_executable(iap_demo)

target_sources(iap_demo PRIVATE
        ${COMMON}/cpu_endian.c
        ${COMMON}/os_port_freertos.c
        ${COMMON}/date_time.c
        ${COMMON}/str.c
        ${COMMON}/path.c
        ${COMMON}/resource_manager.c

        ${UPDATE}/core/crc32.c
        ${UPDATE}/core/mailbox.c
        ${UPDATE}/drivers/mcu_core/stm32l4xx_mcu_driver.c
        ${UPDATE}/drivers/flash/internal/stm32l4xx_flash_driver.c
        ${UPDATE}/modules/image/image.c
        ${UPDATE}/modules/image/image_process.c
        ${UPDATE}/modules/image/image_utils.c
        ${UPDATE}/modules/memory/memory.c
        ${UPDATE}/modules/memory/memory_ex.c
        ${UPDATE}/core/verify.c
        ${UPDATE}/modules/security/verify_auth.c
        ${UPDATE}/modules/security/verify_sign.c
        ${UPDATE}/modules/security/cipher.c
        ${UPDATE}/update/update.c
        ${UPDATE}/update/update_misc.c
        ${UPDATE}/update/update_fallback.c

        ${CRYPTO}/hardware/stm32l4xx/stm32l4xx_crypto.c
        ${CRYPTO}/hardware/stm32l4xx/stm32l4xx_crypto_trng.c
        ${CRYPTO}/hash/md5.c
        ${CRYPTO}/hash/sha1.c
        ${CRYPTO}/hash/sha224.c
        ${CRYPTO}/hash/sha256.c
        ${CRYPTO}/hash/sha384.c
        ${CRYPTO}/hash/sha512.c
        ${CRYPTO}/mac/hmac.c
        ${CRYPTO}/cipher/rc4.c
        ${CRYPTO}/cipher/idea.c
        ${CRYPTO}/cipher/des.c
        ${CRYPTO}/cipher/des3.c
        ${CRYPTO}/cipher/aes.c
        ${CRYPTO}/cipher/camellia.c
        ${CRYPTO}/cipher/seed.c
        ${CRYPTO}/cipher/aria.c
        ${CRYPTO}/cipher_modes/cbc.c
        ${CRYPTO}/aead/ccm.c
        ${CRYPTO}/aead/gcm.c
        ${CRYPTO}/cipher/chacha.c
        ${CRYPTO}/mac/poly1305.c
        ${CRYPTO}/aead/chacha20_poly1305.c
        ${CRYPTO}/pkc/dh.c
        ${CRYPTO}/pkc/rsa.c
        ${CRYPTO}/pkc/dsa.c
        ${CRYPTO}/ecc/ec.c
        ${CRYPTO}/ecc/ec_curves.c
        ${CRYPTO}/ecc/ecdh.c
        ${CRYPTO}/ecc/ecdsa.c
        ${CRYPTO}/ecc/eddsa.c
        ${CRYPTO}/ecc/curve25519.c
        ${CRYPTO}/ecc/curve448.c
        ${CRYPTO}/ecc/x25519.c
        ${CRYPTO}/ecc/x448.c
        ${CRYPTO}/ecc/ed25519.c
        ${CRYPTO}/ecc/ed448.c
        ${CRYPTO}/mpi/mpi.c
        ${CRYPTO}/mpi/mpi_misc.c
        ${CRYPTO}/encoding/base64.c
        ${CRYPTO}/encoding/asn1.c
        ${CRYPTO}/encoding/oid.c
        ${CRYPTO}/pkix/pem_import.c
        ${CRYPTO}/pkix/pem_key_import.c
        ${CRYPTO}/pkix/pem_decrypt.c
        ${CRYPTO}/pkix/pem_common.c
        ${CRYPTO}/pkix/pkcs5_decrypt.c
        ${CRYPTO}/pkix/pkcs5_common.c
        ${CRYPTO}/pkix/pkcs8_key_parse.c
        ${CRYPTO}/pkix/x509_key_parse.c
        ${CRYPTO}/pkix/x509_cert_parse.c
        ${CRYPTO}/pkix/x509_cert_validate.c
        ${CRYPTO}/pkix/x509_cert_ext_parse.c
        ${CRYPTO}/pkix/x509_common.c
        ${CRYPTO}/pkix/x509_sign_parse.c
        ${CRYPTO}/pkix/x509_sign_verify.c
        ${CRYPTO}/kdf/hkdf.c
        
        ${CRYPTO}/ecc/ec_misc.c
        ${CRYPTO}/pkc/rsa_misc.c

        ${THIRD_PARTY}/freertos/portable/gcc/arm_cm4f/port.c
        ${THIRD_PARTY}/freertos/croutine.c
        ${THIRD_PARTY}/freertos/list.c
        ${THIRD_PARTY}/freertos/queue.c
        ${THIRD_PARTY}/freertos/tasks.c
        ${THIRD_PARTY}/freertos/timers.c
        ${THIRD_PARTY}/freertos/portable/memmang/heap_3.c

        ${THIRD_PARTY}/st/boards/stm32l4xx_nucleo/stm32l4xx_nucleo.c

        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal.c
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal_rcc.c
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal_rcc_ex.c
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal_flash.c
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal_flash_ex.c
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal_flash_ramfunc.c
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal_gpio.c
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal_i2c.c
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal_i2c_ex.c
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal_dma.c
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal_dma_ex.c
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal_pwr.c
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal_pwr_ex.c
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal_cortex.c
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal_exti.c
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/src/stm32l4xx_hal_uart.c

        ${CMAKE_SOURCE_DIR}/cmake/startup_stm32l476xx.s
        ${CMAKE_SOURCE_DIR}/cmake/syscalls.c
        ${CMAKE_SOURCE_DIR}/src/system_stm32l4xx.c
        ${CMAKE_SOURCE_DIR}/src/stm32l4xx_it.c
        ${CMAKE_SOURCE_DIR}/src/main.c
        ${CMAKE_SOURCE_DIR}/src/common.c
        ${CMAKE_SOURCE_DIR}/src/uart_user.c
        ${CMAKE_SOURCE_DIR}/src/ymodem.c
        ${CMAKE_SOURCE_DIR}/src/debug.c
        ${CMAKE_SOURCE_DIR}/src/res.c
)

target_include_directories(iap_demo PRIVATE
        ${CMAKE_SOURCE_DIR}/src
        ${THIRD_PARTY}/cmsis/include
        ${THIRD_PARTY}/st/devices/stm32l4xx
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/inc
        ${THIRD_PARTY}/st/drivers/stm32l4xx_hal_driver/inc/legacy
        ${THIRD_PARTY}/st/boards/stm32l4xx_nucleo
        ${THIRD_PARTY}/freertos/include
        ${THIRD_PARTY}/freertos/portable/gcc/arm_cm4f
        ${COMMON}
        ${CRYPTO}
        ${UPDATE}
        ${UPDATE}/modules
)

target_compile_definitions(iap_demo PRIVATE
    STM32L476xx
    STM32L47xG
    USE_HAL_DRIVER
    USE_STM32L4XX_NUCLEO
    __USE_C99_MATH

    $<$<CONFIG:Debug>:DEBUG>
)

# Convert .elf to .bin
add_custom_command(TARGET iap_demo POST_BUILD
        COMMAND ${CMAKE_OBJCOPY} -O binary
        ${CMAKE_CURRENT_BINARY_DIR}/iap_demo.elf
        ${CMAKE_CURRENT_BINARY_DIR}/iap_demo.bin
        COMMENT "Generating binary file from ELF"
)

# Pre-build step: Generate res.c using ResourceCompiler
if(WIN32)
    add_custom_command(
            OUTPUT ${CMAKE_SOURCE_DIR}/src/res.c
            COMMAND ${RESOURCE_COMPILER}/bin/rc.exe
            ${CMAKE_SOURCE_DIR}/resources/
            ${CMAKE_SOURCE_DIR}/src/res.c
            DEPENDS ${CMAKE_SOURCE_DIR}/resources/
            COMMENT "Running Resource Compiler to generate res.c"
    )
else()
    add_custom_command(
            OUTPUT ${CMAKE_SOURCE_DIR}/src/res.c
            COMMAND ${RESOURCE_COMPILER}/bin/rc
            ${CMAKE_SOURCE_DIR}/resources/
            ${CMAKE_SOURCE_DIR}/src/res.c
            DEPENDS ${CMAKE_SOURCE_DIR}/resources/
            COMMENT "Running Resource Compiler to generate res.c"
    )
endif()

# Copy the generated .bin file to ../
set(VERSION_HEADER "${CMAKE_SOURCE_DIR}/src/version.h")
# Read the contents of the header
file(READ "${VERSION_HEADER}" VERSION_HEADER_CONTENT)
# Extract the version string from e.g., #define APP_VERSION "1.0.0"
string(REGEX MATCH "#define APP_VERSION_STRING \"([0-9\\.]+)\"" _ UNUSED ${VERSION_HEADER_CONTENT})
set(APP_VERSION_RAW "${CMAKE_MATCH_1}")
string(REPLACE "." "_" APP_VERSION "${APP_VERSION_RAW}")

configure_file(${VERSION_HEADER} ${CMAKE_CURRENT_BINARY_DIR}/version.h COPYONLY)

message("Detected application version: ${APP_VERSION_RAW}")
add_custom_command(TARGET iap_demo POST_BUILD
        COMMAND ${CMAKE_COMMAND} -E copy
        ${CMAKE_CURRENT_BINARY_DIR}/iap_demo.bin
        ${CMAKE_CURRENT_SOURCE_DIR}/../iap_demo_${APP_VERSION}.bin
        COMMENT "Copying iap_demo.bin to parent directory"
)

if(WIN32)
    add_custom_command(TARGET iap_demo POST_BUILD
            COMMAND ${TOOLS}/ImageBuilder/bin/image_builder_windows.exe
            --input ${CMAKE_CURRENT_SOURCE_DIR}/../iap_demo_${APP_VERSION}.bin
            --output ${CMAKE_CURRENT_SOURCE_DIR}/../iap_demo_${APP_VERSION}_bootable.img.bin
            --vtor-align

            COMMAND ${TOOLS}/ImageBuilder/bin/image_builder_windows.exe
            --input ${CMAKE_CURRENT_SOURCE_DIR}/../iap_demo_${APP_VERSION}.bin
            --output ${CMAKE_CURRENT_SOURCE_DIR}/../iap_demo_${APP_VERSION}_update.img
            --enc-algo aes-cbc
            --enc-key aa3ff7d43cc015682c7dfd00de9379e7
            --sign-algo rsa-sha256
            --sign-key  ./resources/keys/rsa_private_key.pem
            --vtor-align

            COMMENT "Generating iap_demo images using ImageBuilder"
    )
else()
    add_custom_command(TARGET iap_demo POST_BUILD
            COMMAND ${TOOLS}/ImageBuilder/bin/image_builder_linux
            --input ${CMAKE_CURRENT_SOURCE_DIR}/../iap_demo_${APP_VERSION}.bin
            --output ${CMAKE_CURRENT_SOURCE_DIR}/../iap_demo_${APP_VERSION}.img.bin
            --vtor-align

            COMMAND ${TOOLS}/ImageBuilder/bin/image_builder_linux
            --input ${CMAKE_CURRENT_SOURCE_DIR}/../iap_demo_${APP_VERSION}.bin
            --output ${CMAKE_CURRENT_SOURCE_DIR}/../iap_demo_${APP_VERSION}_update.img
            --enc-algo aes-cbc
            --enc-key aa3ff7d43cc015682c7dfd00de9379e7
            --sign-algo rsa-sha256
            --sign-key  ${CMAKE_SOURCE_DIR}/resources/keys/rsa_private_key.pem
            --vtor-align

            COMMENT "Generating iap_demo images using ImageBuilder"
    )
endif ()
